DO
INPUT "Central value of K (include decimal point): ", centre$
IF LEN(centre$) = 1 THEN END
dot% = 1
DO UNTIL MID$(centre$, dot%, 1) = "."
    dot% = dot% + 1
LOOP
offset% = VAL(RIGHT$(LEFT$(centre$, dot% - 1) + RIGHT$(centre$, LEN(centre$) - dot%), 3)) - 320
IF offset% < 0 THEN offset% = offset% + 1000
centre# = VAL(centre$)
unit# = 1
place% = dot%
DO WHILE place% < LEN(centre$)
    unit# = unit# / 10
    place% = place% + 1
LOOP
SCREEN 12
PRINT USING "K range: +###" + STRING$(dot% - 1, "#") + "." + STRING$(LEN(centre$) - dot%, "#") + " to +###" + STRING$(dot% - 1, "#") + "." + STRING$(LEN(centre$) - dot%, "#"); centre# - 320 * unit#; centre# + 319 * unit#
FOR column% = 0 TO 639
    coloff% = (offset% + column%) MOD 1000
    IF coloff% = 0 THEN
        LINE (column%, 19)-(column%, 479), 13
    ELSEIF coloff% = 500 THEN
        LINE (column%, 19)-(column%, 479), 4
    ELSEIF coloff% MOD 100 = 0 THEN
        LINE (column%, 19)-(column%, 479), 10
    ELSEIF coloff% MOD 100 = 50 THEN
        LINE (column%, 19)-(column%, 479), 2
    ELSEIF coloff% MOD 10 = 0 THEN
        LINE (column%, 19)-(column%, 479), 9
    ELSEIF coloff% MOD 10 = 5 THEN
        LINE (column%, 19)-(column%, 479), 1
    END IF
NEXT column%
FOR column% = 0 TO 639
    k# = centre# + (column% - 320) * unit#
    IF k# >= 0 AND k# <= 4 THEN
        pop# = .2
        FOR cycle% = 1 TO 800
            pop# = k# * pop# * (1 - pop#)                   'Change this line
            IF cycle% >= 780 THEN PSET (column%, 479 - pop# * 460), 15
        NEXT cycle%
    END IF
NEXT column%
DO
LOOP UNTIL INKEY$ = ""
DO
LOOP WHILE INKEY$ = ""
SCREEN 0
LOOP